plugins {
    id 'com.android.application'
}

def AppMajorVersion = 1
def AppMinorVersion = 0
def AppBuildNumber = 10

def AppVersionName = AppMajorVersion + "." + AppMinorVersion + "." + AppBuildNumber
def AppVersionCode = AppMajorVersion * 100000 + AppMinorVersion * 1000 + AppBuildNumber

android {
    compileSdk 32

    defaultConfig {
        applicationId "com.xypower.mpremote"
        minSdk 24
        targetSdk 28
        versionCode AppVersionCode
        versionName AppVersionName

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        externalNativeBuild {
            cmake {
                cppFlags "-std=c++11 -frtti -fexceptions"
                arguments "-DENABLE_API=ON", "-DENABLE_API_STATIC_LIB=ON", "-DENABLE_TESTS=OFF", "-DENABLE_PLAYER=OFF", "-DENABLE_SERVER_LIB=ON"
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    externalNativeBuild {
        cmake {
            path file('src/main/cpp/CMakeLists.txt')
            version '3.18.1'
        }
    }

    android.applicationVariants.all { variant ->
        variant.outputs.all { output ->
            if (outputFileName.endsWith('.apk')) {
                def buildTypeFlag = "dbg"
                if(variant.buildType.name.equals('release')) {
                    buildTypeFlag = "rel"
                }
                def fileName = "mprmt_v${defaultConfig.versionName}_${buildTypeFlag}_${new Date(System.currentTimeMillis()).format("yyyyMMdd")}.apk"
                outputFileName = fileName
            }
        }
    }

    buildFeatures {
        viewBinding true
    }

    packagingOptions {
        exclude 'META-INF/LICENSE-notice.md'
        exclude 'META-INF/LICENSE.md'

    }

}

dependencies {

    implementation 'androidx.appcompat:appcompat:1.3.0'
    implementation 'com.google.android.material:material:1.4.0'
    implementation 'androidx.constraintlayout:constraintlayout:2.0.4'
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:1.6.10"

    // https://mvnrepository.com/artifact/dev.mobile/dadb
    implementation 'dev.mobile:dadb:1.2.7'
    implementation files('libs/common-release.aar')
    // implementation project(path: ':dadb')

    testImplementation 'junit:junit:4.13.2'
    androidTestImplementation 'androidx.test.ext:junit:1.1.3'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.4.0'

}